Micro Focus ALM/QC Workflow Configuration to Push Data to ConnectALL

The workflow configuration in Micro Focus ALM/QC would be helpful to enable event-based sync in ConnectALL. This approach eliminates the need of polling ALM/QC for changes. A custom workflow can trigger the sync using the PUSH interface in ConnectALL.

Step-By-Step Guide

1. Navigate to the menu Customize > Workflow
2. Click Script Editor to create a custom workflow event
3. Navigate to Workflow Scripts >> Projects Scripts in the Script Editor.
4. Select the appropriate module (Example, Defects module script)

5. Enter the code snippet provided below into the script editor and save it.

   Sub Bug_AfterPost
     On Error Resume Next
         msgbox "Submitting changes to ConnectALL"
   
         Set objHTTP = CreateObject("MSXML2.ServerXMLHTTP")
         URL = "http://connectall:7070/SyncService/push?apikey=<your-api-key>"
         objHTTP.Open "POST", URL, False
         objHTTP.setRequestHeader "User-Agent", "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.0)"
         objHTTP.setRequestHeader "Content-Type", "application/json; charset=UTF-8"
         objHTTP.setRequestHeader "CharSet", "charset=UTF-8"
         objHTTP.setRequestHeader "Accept", "application/json"
   
         bugID = Bug_Fields("BG_BUG_ID").Value
         ' Send the json in correct format
         json = "{  ""appLinkName"":""JPALM12toJira7"", ""origin"":""destination"", ""id"":""" & bugID & """}"
   
         objHTTP.send (json)
   
         If objHTTP.Status >= 400 And objHTTP.Status <= 599 Then
           msgbox "Error Occurred : " & objHTTP.status & " - " & objHTTP.statusText
         Else
           msgbox "Success : " & objHTTP.status & " - " & objHTTP.ResponseText
         End If
   
     PrintError ("Bug_AfterPost")
     On Error GoTo 0
   End Sub
   
   Sub PrintError(strFunctionName)
           If Err.Number <> 0 Then
               MsgBox "Error #" & Err.Number & ": " & Err.Description, _
               vbOKOnly+vbCritical, _
               "Workflow Error in Function " & strFunctionName
           End If
   End Sub

   VB

     

Please refer our ReST API guide for more details.

Note: Push service is running on the default port of 7070(http://connectall:7070/SyncService/push). Please make sure you make this URL accessible from your Micro Focus ALM/QC instance. A reverse proxy would be the best option to make this service accessible from HPE ALM.